home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 004 / mathstat.arc / S15.BAS (.txt) < prev    next >
Encoding:
GW-BASIC  |  1982-04-14  |  1.5 KB  |  81 lines
  1. 10  PRINT "NTH-ORDER REGRESSION"
  2. 20  PRINT
  3. 30  DIM A(13), R(7,8) , T(8)
  4. 40  PRINT "DEGREE OF EQUATION";
  5. 50  INPUT D
  6. 60  PRINT "NUMBER OF KNOWN POINTS";
  7. 70  INPUT N
  8. 80  A (1) = N
  9. 90  FOR I=1  TO N
  10. 100  PRINT "X,Y OF POINT" ;I;
  11. 110  INPUT X,Y
  12. 120  FOR J=2  TO 2 * D+1
  13. 130  A (J) = A (J) + X ^ (J-1)
  14. 140  NEXT J
  15. 150  FOR K=1  TO D+1
  16. 160  R (K, D+2) = T(K) +Y *X ^ (K-1)
  17. 170  T (K) =T (K) + Y * X ^ (K-1)
  18. 180  NEXT K
  19. 190  T (D+2) = T (D+2) + Y ^ 2
  20. 200  NEXT I
  21. 210  FOR J=1  TO D+1
  22. 220  FOR K=1  TO D+1
  23. 230  R (J,K) = A (J+K-1)
  24. 240  NEXT K
  25. 250  NEXT J
  26. 260  FOR J=1  TO D+1
  27. 270  K =J
  28. 280  IF R(K,J) <> 0  THEN 320
  29. 290  K = K+1
  30. 295  IF K< = D+1  THEN 280
  31. 300  PRINT "NO UNIQUE SOLUTION"
  32. 310  GOTO  790
  33. 320  FOR I =1  TO D+2
  34. 330  S = R (J,I)
  35. 340  R (J,I) = R (K,I)
  36. 350  R (K,I) =S
  37. 360  NEXT I
  38. 370  Z=1 / R (J,J)
  39. 380  FOR I=1  TO D+2
  40. 390  R (J,I) = Z * R (J,I)
  41. 400  NEXT I
  42. 410  FOR K=1  TO D+1
  43. 420  IF K=J  THEN 470
  44. 430  Z =- R (K,J)
  45. 440  FOR I=1  TO D+2
  46. 450  R (K,I) = R (K,I) + Z * R (J,I)
  47. 460  NEXT I
  48. 470  NEXT K
  49. 480  NEXT J
  50. 490  PRINT
  51. 495  PRINT "            CONSTANT ="; R(1,D+2)
  52. 500  FOR J=1  TO D
  53. 510  PRINT J; "DEGREE COEFFICIENT ="; R(J+1, D+2)
  54. 520  NEXT J
  55. 530  PRINT
  56. 540  P =0
  57. 550  FOR J=2  TO D+1
  58. 560  P = P + R (J,D+2) * (T(J) -A (J) * T(1) /N)
  59. 570  NEXT J
  60. 580  Q = T (D+2) - T(1) ^2/N
  61. 590  Z = Q-P
  62. 600  I =N -D - 1
  63. 620  PRINT
  64. 630  J = P/Q
  65. 640  PRINT "COEFFICIENT OF DETERMINATION (R^2) = ";J
  66. 650  PRINT "COEFFICIENT OF CORRLELATION ="; SQR (J)
  67. 660  PRINT "STANDARD ERROR OF ESTIMATE ="; SQR (Z/I)
  68. 670  PRINT
  69. 680  PRINT "INTERPOLATION: (ENTER 0 TO END PROGRAM)"
  70. 690  P = R (1, D+2)
  71. 700  PRINT "X =";
  72. 710  INPUT X
  73. 720  IF X =0  THEN 790
  74. 730  FOR J=1 TO D
  75. 740  P = P + R (J +1, D+2) * X ^ J
  76. 750  NEXT J
  77. 760  PRINT "Y ="; P
  78. 770  PRINT
  79. 780  GOTO  690
  80. 790  RUN "STAT"
  81.